weeDrumster

// ------------------------------
// Teensy Drum-LED Trigger + Start/Stop-Button 
// ------------------------------

#include <Keyboard.h>  // for the foot pedal / space key similation

#include "usb_names.h"

// Check all midi modes so I can give the Teensy a decent name that appears in weeDrumster port selection (I don't know what the internal name for "all of the above" is) :
#if defined(USB_MIDI) || defined(USB_MIDI_SERIAL) || defined(USB_MIDI4_SERIAL) || defined(USB_MIDI_AUDIO_SERIAL) || defined(USB_MIDI_RAWHID) || defined(USB_MIDI_JOYSTICK) || defined(USB_MIDI_RAWHID_SERIAL) || defined(USB_MIDI_AUDIO) || defined(USB_KEYBOARDONLY_RAWHID_MIDI) || defined(USB_MIDI_SERIAL_HID) || defined(USB_ALLMINI) || defined(USB_EVERYTHING)

// port name:
#define PRODUCT_NAME   {'L','E','D','O','u','t'}
#define PRODUCT_NAME_LEN  6

#define MANUFACTURER_NAME {'T','h','e','p','i','x','e','l'}
#define MANUFACTURER_NAME_LEN 8

struct usb_string_descriptor_struct usb_string_product_name = {
  2 + PRODUCT_NAME_LEN * 2,
  3,
  PRODUCT_NAME
};

struct usb_string_descriptor_struct usb_string_manufacturer_name = {
  2 + MANUFACTURER_NAME_LEN * 2,
  3,
  MANUFACTURER_NAME
};

#endif

#define NOTE_KICK   36
#define NOTE_SNARE  38
#define NOTE_HH     42   // all HiHat-Variants  appear as 42, you can split those up and add more LED to your kit of course
#define NOTE_RIDE   51   // all Ride-Variants appear as 51, same here 
#define NOTE_CRASH  49
#define NOTE_TOM1   48
#define NOTE_TOM2   45
#define NOTE_TOM3   43

// LED Pins
#define LED_KICK   1
#define LED_SNARE  2
#define LED_HH     3
#define LED_CRASH  4
#define LED_RIDE   6
#define LED_TOM1   8
#define LED_TOM2   10
#define LED_TOM3   12

// Button-Pin
#define BUTTON_PIN 11                                                                                

// internal Teensy LED
#define LED_INTERNAL  13

// Full brightness
#define PULSE_BRIGHTNESS  255
#define DECAY_SPEED       5      

int ledLevel[8] = {0};
                         
// Button-handling
bool lastButtonState = HIGH;
unsigned long lastButtonChange = 0;
const unsigned long debounceMs = 25;

// Internal LED blink
bool blinkState = false;
unsigned long lastBlink = 0;
const unsigned long blinkInterval = 120;  //blink speed

void setup() {
  // LED Pins
  pinMode(LED_KICK,  OUTPUT);
  pinMode(LED_SNARE, OUTPUT);
  pinMode(LED_HH,    OUTPUT);
  pinMode(LED_CRASH, OUTPUT);
  pinMode(LED_RIDE,  OUTPUT);
  pinMode(LED_TOM1,  OUTPUT);
  pinMode(LED_TOM2,  OUTPUT);
  pinMode(LED_TOM3,  OUTPUT);

  // internal LED
  pinMode(LED_INTERNAL, OUTPUT);
  digitalWrite(LED_INTERNAL, LOW);

  // Button
  pinMode(BUTTON_PIN, INPUT_PULLUP);

  // prepare "Keyboard"
  Keyboard.begin();
}

void loop() {

  // read MIDI
  while (usbMIDI.read()) {
    if (usbMIDI.getType() == usbMIDI.NoteOn &&
        usbMIDI.getData2() > 0) {

      triggerLed(usbMIDI.getData1());
    }
  }

  // LEDs soft off
  for (int i = 0; i < 8; i++) {
    if (ledLevel[i] > 0) {
      ledLevel[i] -= DECAY_SPEED;
      if (ledLevel[i] < 0) ledLevel[i] = 0;
    }
  }

  // write LEDs 
  analogWrite(LED_KICK,  ledLevel[0]);
  analogWrite(LED_SNARE, ledLevel[1]);
  analogWrite(LED_HH,    ledLevel[2]);
  analogWrite(LED_CRASH, ledLevel[3]);
  analogWrite(LED_RIDE,  ledLevel[4]);
  analogWrite(LED_TOM1,  ledLevel[5]);
  analogWrite(LED_TOM2,  ledLevel[6]);
  analogWrite(LED_TOM3,  ledLevel[7]);

  // watch button
  handleButton();

  delay(4);
}

void triggerLed(int note) {
if (note == NOTE_KICK)        ledLevel[0] = PULSE_BRIGHTNESS;
else if (note == NOTE_SNARE)  ledLevel[1] = PULSE_BRIGHTNESS;
else if (note == NOTE_HH)     ledLevel[2] = PULSE_BRIGHTNESS;
else if (note == NOTE_CRASH)  ledLevel[3] = PULSE_BRIGHTNESS;
else if (note == NOTE_RIDE)   ledLevel[4] = PULSE_BRIGHTNESS;
else if (note == NOTE_TOM1)   ledLevel[5] = PULSE_BRIGHTNESS;
else if (note == NOTE_TOM2)   ledLevel[6] = PULSE_BRIGHTNESS;
else if (note == NOTE_TOM3)   ledLevel[7] = PULSE_BRIGHTNESS;

}

void handleButton() {
  int state = digitalRead(BUTTON_PIN);
  unsigned long now = millis();

  // make sure your button isn't nervous ;-) 
  if (state != lastButtonState && (now - lastButtonChange) > debounceMs) {
    lastButtonChange = now;
    lastButtonState = state;

    if (state == LOW) {
      sendSpaceKey();
    }
  }

  // flash internal LED when button pressed
  if (state == LOW) {
    if (now - lastBlink > blinkInterval) {
      lastBlink = now;
      blinkState = !blinkState;
      digitalWrite(LED_INTERNAL, blinkState ? HIGH : LOW);
    }
  } else {
    // internal LED of when button released
    digitalWrite(LED_INTERNAL, LOW);
  }
}

void sendSpaceKey() {
  Keyboard.press(' ');
  delay(10);
  Keyboard.release(' ');
}